src/graph/lca.cr

View this file on GitHub
Last update: 2022-04-16 16:23:13+09:00

Depends on

Verified with

Code

require "../graph"

class LCA(Edge, Edge2)
  getter graph : Graph(Edge, Edge2), depth : Array(Int32), log2 : Int32

  private def dfs(vertex : Int32, par : Int32, dep : Int32) : Nil
    @parent[0][vertex] = par
    @depth[vertex] = dep
    @graph[vertex].each do |edge|
      dfs(edge.to, vertex, dep + 1) if edge.to != par
    end
  end

  def initialize(@graph : Graph(Edge, Edge2), root : Int32)
    @log2 = Math.log2(size).to_i.succ
    @depth = Array(Int32).new(size, -1)
    @parent = Array(Array(Int32)).new(log2) { Array.new(size, 0) }
    dfs(root, -1, 0)
    (0...log2 - 1).each do |k|
      (0...size).each do |v|
        @parent[k + 1][v] = @parent[k][v] < 0 ? -1 : @parent[k][@parent[k][v]]
      end
    end
  end

  delegate size, to: @graph

  def depth(v : Int32) : Int32
    @depth[v]
  end

  def parent_p2(v : Int32, k : Int32) : Int32?
    p = @parent[k][v]
    p >= 0 ? p : nil
  end

  def parent_p2!(v : Int32, k : Int32) : Int32
    parent_p2(v, k).not_nil!
  end

  def parent(v : Int32) : Int32?
    parent_p2(v, 0)
  end

  def parent!(v : Int32) : Int32
    parent(v).not_nil!
  end

  def parent(v : Int32, up : Int32) : Int32?
    log2.times do |k|
      v = @parent[k][v] if up.bit(k) == 1
      return nil if v < 0
    end
    v
  end

  def parent!(v : Int32, up : Int32) : Int32
    parent(v, up).not_nil!
  end

  def lca(u : Int32, v : Int32) : Int32
    raise IndexError.new unless 0 <= u < size && 0 <= v < size
    u, v = v, u if @depth[u] > @depth[v]
    (0...log2).each do |k|
      v = @parent[k][v] if (@depth[v] - @depth[u]).bit(k) == 1
    end

    return u if u == v

    (0...log2).reverse_each do |k|
      u, v = @parent[k][u], @parent[k][v] if @parent[k][u] != @parent[k][v]
    end
    @parent[0][u]
  end

  def dist(u : Int32, v : Int32) : Int32
    depth(u) + depth(v) - depth(lca(u, v)) * 2
  end

  def path(start : Int32, goal : Int32, &) : Nil
    lca = lca(start, goal)
    {start, goal}.each do |first|
      if first != lca
        yield v = first
        while (v = parent!(v)) != lca
          yield v
        end
      end
    end
    yield lca
  end

  def path(start : Int32, goal : Int32) : Array(Int32)
    path = [] of Int32
    path(start, goal) { |v| path << v }
    path
  end
end

# require "../graph"
# require "./graph/edge"
struct WeightedEdge(T)
  include Comparable(WeightedEdge(T))

  property to : Int32, cost : T

  def initialize(@to, @cost : T)
  end

  def <=>(other : WeightedEdge(T))
    {cost, to} <=> {other.cost, other.to}
  end

  def to_s(io) : Nil
    io << '(' << to << ", " << cost << ')'
  end

  def inspect(io) : Nil
    io << "->" << to << '(' << cost << ')'
  end
end

struct WeightedEdge2(T)
  include Comparable(WeightedEdge2(T))

  property from : Int32, to : Int32, cost : T

  def initialize(@from, @to, @cost : T)
  end

  def initialize(@from, edge : WeightedEdge(T))
    @to, @cost = edge.to, edge.cost
  end

  def <=>(other : WeightedEdge2(T))
    {cost, from, to} <=> {other.cost, other.from, other.to}
  end

  def reverse : self
    WeightedEdge2(T).new(to, from, cost)
  end

  def sort : self
    WeightedEdge2(T).new(*{to, from}.minmax, cost)
  end

  def to_s(io) : Nil
    io << '(' << from << ", " << to << ", " << cost << ')'
  end

  def inspect(io) : Nil
    io << from << "->" << to << '(' << cost << ')'
  end
end

struct UnweightedEdge
  property to : Int32

  def initialize(@to)
  end

  def initialize(@to, cost)
  end

  def cost : Int32
    1
  end

  def to_s(io) : Nil
    io << to
  end

  def inspect(io) : Nil
    io << "->" << to
  end
end

struct UnweightedEdge2
  property from : Int32, to : Int32

  def initialize(@from, @to)
  end

  def initialize(@from, @to, cost)
  end

  def initialize(@from, edge : UnweightedEdge)
    @to = edge.to
  end

  def cost : Int32
    1
  end

  def reverse : self
    UnweightedEdge2.new(to, from)
  end

  def sort : self
    UnweightedEdge2.new(*{to, from}.minmax)
  end

  def to_s(io) : Nil
    io << '(' << from << ", " << to << ')'
  end

  def inspect(io) : Nil
    io << from << "->" << to
  end
end

module Graph(Edge, Edge2)
  include Enumerable(Edge2)

  getter graph : Array(Array(Edge))

  def initialize(size : Int)
    @graph = Array(Array(Edge)).new(size) { [] of Edge }
  end

  def initialize(size : Int, edges : Enumerable)
    initialize(size)
    add_edges(edges)
  end

  # Add *edge*.
  abstract def <<(edge : Edge2)

  # :ditto:
  def <<(edge : Tuple) : self
    self << Edge2.new(*edge)
  end

  def add_edges(edges : Enumerable) : self
    edges.each { |edge| self << edge }
    self
  end

  delegate size, :[], to: @graph

  # Yields each edge of the graph, ans returns `nil`.
  def each(&) : Nil
    (0...size).each do |v|
      graph[v].each do |edge|
        yield Edge2.new(v, edge)
      end
    end
  end

  def each_child(vertex : Int, parent, &block) : Nil
    graph[vertex].each do |edge|
      yield edge if edge.to != parent
    end
  end

  def each_child(vertex : Int, parent)
    graph[vertex].each.reject(&.to.== parent)
  end

  def reverse : self
    if self.class.directed?
      each_with_object(self.class.new(size)) do |edge, reversed|
        reversed << edge.reverse
      end
    else
      dup
    end
  end

  def to_undirected : self
    if self.class.directed?
      each_with_object(self.class.new(size)) do |edge, graph|
        graph << edge << edge.reverse
      end
    else
      dup
    end
  end

  def to_s(io : IO) : Nil
    io << '['
    join(", ", io) do |edge, io|
      edge.inspect io
    end
    io << ']'
  end

  def inspect(io : IO) : Nil
    io << "[\n"
    graph.each do |edges|
      io << "  " << edges << ",\n"
    end
    io << ']'
  end
end

class DiGraph(T)
  include Graph(WeightedEdge(T), WeightedEdge2(T))

  def self.weighted?
    true
  end

  def self.directed?
    true
  end

  def initialize(size : Int)
    super
  end

  def initialize(size : Int, edges : Enumerable(WeightedEdge2(T)))
    super
  end

  def initialize(size : Int, edges : Enumerable({Int32, Int32, T}))
    super
  end

  def <<(edge : WeightedEdge2(T)) : self
    raise IndexError.new unless 0 <= edge.from < size && 0 <= edge.to < size
    @graph[edge.from] << WeightedEdge.new(edge.to, edge.cost)
    self
  end
end

class UnGraph(T)
  include Graph(WeightedEdge(T), WeightedEdge2(T))

  def self.weighted?
    true
  end

  def self.directed?
    false
  end

  def initialize(size : Int)
    super
  end

  def initialize(size : Int, edges : Enumerable(WeightedEdge2(T)))
    super
  end

  def initialize(size : Int, edges : Enumerable({Int32, Int32, T}))
    super
  end

  def <<(edge : WeightedEdge2(T)) : self
    raise IndexError.new unless 0 <= edge.from < size && 0 <= edge.to < size
    @graph[edge.from] << WeightedEdge.new(edge.to, edge.cost)
    @graph[edge.to] << WeightedEdge.new(edge.from, edge.cost)
    self
  end
end

class UnweightedDiGraph
  include Graph(UnweightedEdge, UnweightedEdge2)

  def self.weighted?
    false
  end

  def self.directed?
    true
  end

  def initialize(size : Int)
    super
  end

  def initialize(size : Int, edges : Enumerable)
    super
  end

  def <<(edge : UnweightedEdge2) : self
    raise IndexError.new unless 0 <= edge.from < size && 0 <= edge.to < size
    @graph[edge.from] << UnweightedEdge.new(edge.to)
    self
  end
end

class UnweightedUnGraph
  include Graph(UnweightedEdge, UnweightedEdge2)

  def self.weighted?
    false
  end

  def self.directed?
    false
  end

  def initialize(size : Int)
    super
  end

  def initialize(size : Int, edges : Enumerable)
    super
  end

  def <<(edge : UnweightedEdge2) : self
    raise IndexError.new unless 0 <= edge.from < size && 0 <= edge.to < size
    @graph[edge.from] << UnweightedEdge.new(edge.to)
    @graph[edge.to] << UnweightedEdge.new(edge.from)
    self
  end
end

class LCA(Edge, Edge2)
  getter graph : Graph(Edge, Edge2), depth : Array(Int32), log2 : Int32

  private def dfs(vertex : Int32, par : Int32, dep : Int32) : Nil
    @parent[0][vertex] = par
    @depth[vertex] = dep
    @graph[vertex].each do |edge|
      dfs(edge.to, vertex, dep + 1) if edge.to != par
    end
  end

  def initialize(@graph : Graph(Edge, Edge2), root : Int32)
    @log2 = Math.log2(size).to_i.succ
    @depth = Array(Int32).new(size, -1)
    @parent = Array(Array(Int32)).new(log2) { Array.new(size, 0) }
    dfs(root, -1, 0)
    (0...log2 - 1).each do |k|
      (0...size).each do |v|
        @parent[k + 1][v] = @parent[k][v] < 0 ? -1 : @parent[k][@parent[k][v]]
      end
    end
  end

  delegate size, to: @graph

  def depth(v : Int32) : Int32
    @depth[v]
  end

  def parent_p2(v : Int32, k : Int32) : Int32?
    p = @parent[k][v]
    p >= 0 ? p : nil
  end

  def parent_p2!(v : Int32, k : Int32) : Int32
    parent_p2(v, k).not_nil!
  end

  def parent(v : Int32) : Int32?
    parent_p2(v, 0)
  end

  def parent!(v : Int32) : Int32
    parent(v).not_nil!
  end

  def parent(v : Int32, up : Int32) : Int32?
    log2.times do |k|
      v = @parent[k][v] if up.bit(k) == 1
      return nil if v < 0
    end
    v
  end

  def parent!(v : Int32, up : Int32) : Int32
    parent(v, up).not_nil!
  end

  def lca(u : Int32, v : Int32) : Int32
    raise IndexError.new unless 0 <= u < size && 0 <= v < size
    u, v = v, u if @depth[u] > @depth[v]
    (0...log2).each do |k|
      v = @parent[k][v] if (@depth[v] - @depth[u]).bit(k) == 1
    end

    return u if u == v

    (0...log2).reverse_each do |k|
      u, v = @parent[k][u], @parent[k][v] if @parent[k][u] != @parent[k][v]
    end
    @parent[0][u]
  end

  def dist(u : Int32, v : Int32) : Int32
    depth(u) + depth(v) - depth(lca(u, v)) * 2
  end

  def path(start : Int32, goal : Int32, &) : Nil
    lca = lca(start, goal)
    {start, goal}.each do |first|
      if first != lca
        yield v = first
        while (v = parent!(v)) != lca
          yield v
        end
      end
    end
    yield lca
  end

  def path(start : Int32, goal : Int32) : Array(Int32)
    path = [] of Int32
    path(start, goal) { |v| path << v }
    path
  end
end